#compdef udevadm
# SPDX-License-Identifier: LGPL-2.1-or-later
# udevadm(8) completion, adapted from the one of systemd.

(( $+functions[_udevadm_info] )) ||
_udevadm_info(){
    _arguments \
        '(-)'{-h,--help}'[Print help]' \
        '(-)'{-V,--version}'[Print version of the program]' \
        '--query=[Query the database for specified type of device data. It needs the --path or --name to identify the specified device.]:type:(name symlink path property all)' \
        '*--path=[The devpath of the device to query.]:sys files:_files -W /sys' \
        '*--name=[The name of the device node or a symlink to query]:device files:_files -W /dev' \
        '--root[Print absolute paths in name or symlink query.]' \
        '--attribute-walk[Print all sysfs properties of the specified device that can be used in udev rules to match the specified device]' \
        '--tree[Show tree of devices.]' \
        '--export[Print output as key/value pairs.]' \
        '--export-prefix=[Add a prefix to the key name of exported values.]:prefix' \
        '--device-id-of-file=[Print major/minor numbers of the underlying device, where the file lives on.]:files:_udevadm_mounts' \
        '--export-db[Export the content of the udev database.]' \
        '--cleanup-db[Cleanup the udev database.]' \
        '--value[When showing properties, print only their values.]' \
        '*--property=[Show only properties by this name.]:NAME' \
        '--wait-for-initialization=-[Wait for device to be initialized.]:SECS' \
        '--json=[Generate JSON output]:MODE:(pretty short off)' \
        '--no-pager[Do not pipe output into a pager.]' \
        '*--subsystem-match=[When used with --export-db, only show devices of the given subsystem.]:SUBSYSTEM' \
        '*--subsystem-nomatch=[When used with --export-db, only show devices not of the given subsystem.]:SUBSYSTEM' \
        '*--attr-match=[When used with --export-db, only show devices matching the given attribute.]:FILE[=VALUE]' \
        '*--attr-nomatch=[When used with --export-db, only show devices not matching the given attribute.]:FILE[=VALUE]' \
        '*--property-match=[When used with --export-db, only show devices matching the given property and value.]:KEY=VALUE' \
        '*--tag-match=[When used with --export-db, only show devices with the given tag.]:TAG' \
        '*--sysname-match=[When used with --export-db, only show devices with the given /sys path.]:NAME' \
        '*--name-match=[When used with --export-db, only show devices with the given name in /dev.]:device files:_files -W /dev' \
        '*--parent-match=[When used with --export-db, only show devices with the given parent device.]:sys files:_files -W /sys' \
        '--initialized-match[When used with --export-db, only show devices that are initialized.]' \
        '--initialized-nomatch[When used with --export-db, only show devices that are not initialized.]' \
        '*::devpath:_path_files -g "*(-/,-%)"'
}

(( $+functions[_udevadm_trigger] )) ||
_udevadm_trigger(){
    _arguments \
        '(-)'{-h,--help}'[Show help]' \
        '(-)'{-V,--version}'[Show package version]' \
        '(-v --verbose)'{-v,--verbose}'[Print the list of devices which will be triggered.]' \
        '(-n --dry-run)'{-n,--dry-run}'[Do not actually trigger the event.]' \
        '(-q --quiet)'{-q,--quiet}'[Suppress error logging in triggering events.]' \
        '(-t --type)'{-t,--type=}'[Trigger a specific type of devices.]:types:(all devices subsystems)' \
        '(-c --action)'{-c,--action=}'[Type of event to be triggered.]:actions:(add change remove move online offline bind unbind)' \
        '*'{-s,--subsystem-match=}'[Trigger events for devices which belong to a matching subsystem.]:SUBSYSTEM' \
        '*'{-S,--subsystem-nomatch=}'[Do not trigger events for devices which belong to a matching subsystem.]:SUBSYSTEM' \
        '*'{-a,--attr-match=}'[Trigger events for devices with a matching sysfs attribute.]:FILE[=VALUE]' \
        '*'{-A,--attr-nomatch=}'[Do not trigger events for devices with a matching sysfs attribute.]:FILE[=VALUE]' \
        '*'{-p,--property-match=}'[Trigger events for devices with a matching property value.]:KEY=VALUE' \
        '*'{-g,--tag-match=}'[Trigger events for devices with a matching tag.]:TAG' \
        '*'{-y,--sysname-match=}'[Trigger events for devices with a matching sys device name.]:NAME' \
        '*--name-match=[Trigger events for devices with a matching device path.]:device files:_files -W /dev' \
        '*'{-b,--parent-match=}'[Trigger events for all children of a given device.]:NAME' \
        '--include-parents[Also trigger parent devices of found devices.]' \
        '--initialized-match[Trigger events for devices that are already initialized.]' \
        '--initialized-nomatch[Trigger events for devices that are not initialized yet.]' \
        '(-w --settle)'{-w,--settle}'[Wait for the triggered events to complete.]' \
        '--wait-daemon=-[Wait for udevd daemon to be initialized before triggering uevents.]:SECONDS' \
        '--uuid[Print synthetic uevent UUID.]' \
        '*--prioritized-subsystem=[Trigger events for devices which belong to a matching subsystem earlier.]:SUBSYSTEM' \
        '*::devpath:_path_files -g "*(-/,-%)"'
}

(( $+functions[_udevadm_settle] )) ||
_udevadm_settle(){
    _arguments \
        '(-)'{-h,--help}'[Print help]' \
        '(-)'{-V,--version}'[Print version of the program]' \
        '(-t --timeout)'{-t,--timeout=}'[Maximum number of seconds to wait for the event queue to become empty.]:SEC' \
        '(-E --exit-if-exists)'{-E,--exit-if-exists=}'[Stop waiting if file exists.]:files:_files'
}

(( $+functions[_udevadm_control] )) ||
_udevadm_control(){
    _arguments \
        '(-)'{-h,--help}'[Show help]' \
        '(-)'{-V,--version}'[Show package version]' \
        '(-e --exit)'{-e,--exit}'[Signal and wait for udevd to exit.]' \
        '(-l --log-level --log-priority)'{-l,--log-level=,--log-priority=}'[Set the internal log level of udevd.]:LEVEL:(alert crit debug emerg err info notice warning)' \
        '(-s --stop-exec-queue)'{-s,--stop-exec-queue}'[Signal udevd to stop executing new events. Incoming events will be queued.]' \
        '(-S --start-exec-queue)'{-S,--start-exec-queue}'[Signal udevd to enable the execution of events.]' \
        '(-R --reload)'{-R,--reload}'[Signal udevd to reload the rules files and other databases like the kernel module index.]' \
        '*'{-p,--property=}'[Set a global property for all events.]:KEY=VALUE' \
        '(-m --children-max)'{-m,--children-max=}'[Set the maximum number of events.]:N' \
        '--ping[Send a ping message to udevd and wait for the reply.]' \
        '--trace=[Enable/disable trace logging.]:BOOL' \
        '--revert[Revert previously set configurations.]' \
        '(-t --timeout)'{-t,--timeout=}'[The maximum number of seconds to wait for a reply from udevd.]:SECONDS'
}

(( $+functions[_udevadm_monitor] )) ||
_udevadm_monitor(){
    _arguments \
        '(-)'{-h,--help}'[Show help]' \
        '(-)'{-V,--version}'[Show package version]' \
        '(-k --kernel)'{-k,--kernel}'[Print the kernel uevents.]' \
        '(-u --udev)'{-u,--udev}'[Print the udev event after the rule processing.]' \
        '(-p --property)'{-p,--property}'[Also print the properties of the event.]' \
        '*'{-s,--subsystem-match=}'[Filter events by subsystem/\[devtype\].]:SUBSYSTEM' \
        '*'{-t,--tag-match=}'[Filter events by tag.]:TAG'
}

(( $+functions[_udevadm_hwdb] )) ||
_udevadm_hwdb(){
    _arguments \
        '(-)'{-h,--help}'[Show help]' \
        '(-)'{-V,--version}'[Show package version]' \
        '(-u --update)'{-u,--update}'[Update the hardware database.]' \
        '(-s --strict)'{-s,--strict}'[When updating, return non-zero exit value on any parsing error.]' \
        '--usr[Generate in the udev library directory instead of /etc/udev.]' \
        '(-o --output)'{-o,--output=}'[Generate the database in the specified file.]:files:_files' \
        '(-t --test)'{-t,--test=}'[Query the database and print the result.]:MODALIAS' \
        '(-r --root)'{-r,--root=}'[Alternative root path in the filesystem.]:directories:_directories'
}

(( $+functions[_udevadm_test] )) ||
_udevadm_test(){
    _arguments \
        '(-)'{-h,--help}'[Show help]' \
        '(-)'{-V,--version}'[Show package version]' \
        '(-a --action)'{-a,--action=}'[The action string.]:actions:(add change remove move online offline bind unbind)' \
        '(-N --resolve-names)'{-N,--resolve-names=}'[When to resolve names.]:resolve:(early late never)' \
        '*'{-D,--extra-rules-dir=}'[Also load rules from the directory.]:directories:_directories' \
        '(-v --verbose)'{-v,--verbose}'[Show verbose logs.]' \
        '--json=[Generate JSON output]:MODE:(pretty short off)' \
        '*::devpath:_udevadm_devices'
}

(( $+functions[_udevadm_test-builtin] )) ||
_udevadm_test-builtin(){
    _arguments \
        '(- *)'{-h,--help}'[Print help]' \
        '(- *)'{-V,--version}'[Print version of the program]' \
        '(-a --action)'{-a,--action=}'[The action string.]:actions:(add change remove move online offline bind unbind)' \
        ':builtins:(blkid btrfs factory_reset hwdb input_id keyboard kmod net_driver net_id path_id tpm2_id usb_id)' \
        ':devpath:_udevadm_devices'
}

(( $+functions[_udevadm_verify] )) ||
_udevadm_verify(){
    _arguments \
        '(- *)'{-h,--help}'[Show help]' \
        '(- *)'{-V,--version}'[Show package version]' \
        '(-N --resolve-names)'{-N,--resolve-names=}'[When to resolve names.]:resolve:(early late never)' \
        '--root=[Operate on catalog hierarchy under specified directory]:directories:_directories' \
        --no-summary'[Do not show summary.]' \
        --no-style'[Ignore style issues.]' \
        '*::files:_files'
}

(( $+functions[_udevadm_cat] )) ||
_udevadm_cat(){
    _arguments \
        '(- *)'{-h,--help}'[Show help]' \
        '(- *)'{-V,--version}'[Show package version]' \
        '--root=[Operate on catalog hierarchy under specified directory]:directories:_directories' \
        --tldr'[Skip comments and empty lines.]' \
        --config'[Show udev.conf.]' \
        '*::files:_files'
}

(( $+functions[_udevadm_wait] )) ||
_udevadm_wait(){
    _arguments \
        '(- *)'{-h,--help}'[Print help]' \
        '(- *)'{-V,--version}'[Print version of the program]' \
        '(-t --timeout)'{-t,--timeout=}'[Maximum number of seconds to wait for the devices being created.]:SEC' \
        '--initialized=[Wait for devices being initialized by udevd.]:boolean:(yes no)' \
        '--removed[Wait for devices being removed.]' \
        '--settle[Also wait for udev queue being empty.]' \
        '*::devpath:_udevadm_wait_devices'
}

(( $+functions[_udevadm_wait_devices] )) ||
_udevadm_wait_devices(){
    # udevadm wait takes absolute paths below /dev and /sys: device nodes and their symlinks in /dev,
    # also for a name relative to /dev, and sysfs paths
    if [[ $PREFIX == /sys/* ]]; then
        _files
    elif [[ $PREFIX != /* || $PREFIX == /dev/* ]]; then
        _files -W /dev -P /dev/ -g "*(-%)"
    else
        compadd -S '' -- /dev/ /sys/
    fi
}

(( $+functions[_udevadm_lock] )) ||
_udevadm_lock(){
    _arguments \
        '(- *)'{-h,--help}'[Print help]' \
        '(- *)'{-V,--version}'[Print version of the program]' \
        '(-t --timeout)'{-t,--timeout=}'[Maximum number of seconds to wait for the devices being locked.]:SECS' \
        '(-d --device)'{-d,--device=}'[Block device to lock.]:DEVICE:_files -W /dev' \
        '(-b --backing)'{-b,--backing=}'[File whose backing block device to lock.]:FILE:_files' \
        '(-p --print)'{-p,--print}'[Only show which block device the lock would be taken on.]' \
        '*::command:_normal'
}

(( $+functions[_udevadm_devices] )) ||
_udevadm_devices(){
    local -a alts

    # sysfs paths, also relative to /sys, and device nodes in /dev, or other absolute paths
    [[ $PREFIX != /* || $PREFIX == /sys/* ]] && alts+=( 'sysfs-paths:sysfs path:_files -W /sys' )
    [[ $PREFIX != /* || $PREFIX == /dev/* ]] && alts+=( 'device-nodes:device node:_files -W /dev -P /dev/ -g "*(-%)"' )
    (( $#alts )) || alts=( 'files:file:_files' )
    _alternative $alts
}

(( $+functions[_udevadm_mounts] )) ||
_udevadm_mounts(){
    local dev_tmp dpath_tmp mp_tmp mline

    tmp=( "${(@f)$(< /proc/self/mounts)}" )
    dev_tmp=( "${(@)${(@)tmp%% *}:#none}" )
    mp_tmp=( "${(@)${(@)tmp#* }%% *}" )

    local MATCH
    mp_tmp=("${(@q)mp_tmp//(#m)\\[0-7](#c3)/${(#)$(( 8#${MATCH[2,-1]} ))}}")
    dpath_tmp=( "${(@Mq)dev_tmp:#/*}" )
    dev_tmp=( "${(@q)dev_tmp:#/*}" )

    _alternative \
        'device-paths: device path:compadd -a dpath_tmp' \
        'directories:mount point:compadd -a mp_tmp'
}

(( $+functions[_udevadm_commands] )) ||
_udevadm_commands(){
    local -a _udevadm_cmds
    _udevadm_cmds=(
        'help:show this help'
        'info:query sysfs or the udev database'
        'trigger:request events from the kernel'
        'settle:wait for the event queue to finish'
        'control:control the udev daemon'
        'monitor:listen to kernel and udev events'
        'hwdb:maintain the hardware database index'
        'test:test an event run'
        'test-builtin:test a built-in command'
        'verify:verify udev rules files'
        'cat:show udev rules files'
        'wait:wait for devices or device symlinks being created'
        'lock:lock a block device and run a command'
        'version:show package version'
    )

    if ((CURRENT == 1)); then
        _describe -t commands 'udevadm commands' _udevadm_cmds
    else
        local curcontext="$curcontext"
        cmd="${${_udevadm_cmds[(r)$words[1]:*]%%:*}}"
        if (($#cmd)); then
            if (( $+functions[_udevadm_$cmd] )); then
                _udevadm_$cmd
            elif [[ $cmd == (help|version) ]]; then
                # nothing to complete, and nothing to say, after help and version
                return 1
            else
                _message "no options for $cmd"
            fi
        else
            _message "no more options"
        fi
    fi
}

_arguments \
    '(-d --debug)'{-d,--debug}'[Print debug messages to stderr]' \
    '(- *)'{-V,--version}'[Print version number]' \
    '(- *)'{-h,--help}'[Print help text]' \
    '*::udevadm commands:_udevadm_commands'
